#
# ~/.config/fish/configs/arch_config.fish
#

source $HOME/.config/fish/configs/uni.fish

function updateall
    # Get current Discord version (if installed)
    if pacman -Q discord >/dev/null 2>&1
        set discord_version_before (pacman -Q discord)
    else
        set discord_version_before ""
    end

    if pacman -Q linux-zen >/dev/null 2>&1
        set kernel_version_before (pacman -Q linux-zen)
    else
        set kernel_version_before ""
    end

    # Run updates
    sudo pacman -Syu

    # Get new Discord version (if installed)
    if pacman -Q discord >/dev/null 2>&1
        set discord_version_after (pacman -Q discord)
    else
        set discord_version_after ""
    end

    # Compare discord versions
    if test "$discord_version_before" != "$discord_version_after"
        echo "Discord version changed: $discord_version_before -> $discord_version_after"
        if test -e /usr/bin/curl
            echo "Running Vencord installer..."
            sh -c "$(curl -sS https://raw.githubusercontent.com/Vendicated/VencordInstaller/main/install.sh)"
        else
            echo "'curl' is not installed. Install it to update Discord plugins."
        end
    end

    if test -e /usr/bin/flatpak
        flatpak update
    end
    if test -e /usr/bin/paru
        paru -Sua --sudoloop
    else if test -e /usr/bin/yay
        yay -Sua --sudoloop
    end
    # Get new Discord version (if installed)
    if pacman -Q linux-zen >/dev/null 2>&1
        set kernel_version_after (pacman -Q linux-zen)
    else
        set kernel_version_after ""
    end
    if test "$kernel_version_before" != "$kernel_version_after"
        echo "Kernel changed: $kernel_version_before -> $kernel_version_after"
        echo -n "Reboot now? [y/N]: "

        read answer

        if test "$answer" = "y" -o "$answer" = "Y"
            reboot
        else
            echo "Skipping reboot."
        end
    end
end

alias fixpacman='sudo rm -f /var/lib/pacman/db.lck'

if test -e /usr/bin/expac
    alias rip='expac --timefmt="%Y-%m-%d %T" "%l\t%n %v" | sort | tail -200 | nl'
    alias big='expac -H M "%m\t%n" | sort -h | nl'
else
    alias rip="echo 'expac is not installed. Install it to list last deinstalled packages.'"
    alias big="echo 'expac is not installed. Install it to list biggest packages.'"
end

function cleanup
    while pacman -Qdtq >/dev/null 2>&1
        set orphans (pacman -Qdtq 2>/dev/null)
        if test -z "$orphans"
            break
        end
        sudo pacman -R $orphans
    end
    echo "No more orphaned packages."
end

if test -x $HOME/.local/python-3.11.9/bin/python3.11
    alias py311="$HOME/.local/python-3.11.9/bin/python3.11"
end

if test -e /usr/bin/tmux
    function quickshell-reload
        if test -e /usr/bin/quickshell
            tmux kill-session -t qs 2>/dev/null
            tmux new-session -d -s qs 'quickshell'
        else
            echo "'quickshell' is not installed. Install it via your package manager."
        end
    end
else
    function quickshell-reload
        echo "'tmux' is not installed. Install it via your package manager."
    end
end

if test -e /usr/bin/reflector
    alias mirror='sudo reflector -f 30 -l 30 --number 10 --verbose --save /etc/pacman.d/mirrorlist'
    alias mirrora='sudo reflector --latest 50 --number 20 --sort age --save /etc/pacman.d/mirrorlist'
    alias mirrord='sudo reflector --latest 50 --number 20 --sort delay --save /etc/pacman.d/mirrorlist'
    alias mirrors='sudo reflector --latest 50 --number 20 --sort score --save /etc/pacman.d/mirrorlist'
end